1 REM MAG PRINTER V3.4
2 REM (C) 1986 DAVID A. HOOK
10 A$="ABCDEFGHIJKLMNOPQRST": A$=A$+A$
30 REM ISSUE FILE NAME
40 READ F$
60 PRINT "[147]"; TAB(12); "[205][193][199][193][218][201][206][197] [208][210][201][206][212][197][210]"
70 PRINT TAB(9); "(C) 1986 [196]AVID [193]. [200]OOK"
80 PRINT"  [211]END THE [205]AGAZINE [201]SSUE TO A [208]RINTER  OR THE [211]CREEN."
90 PRINT "  [207]NCE STARTED, [208]AUSE BY STRIKING A KEY"
100 PRINT " [210]ESUME/[209]UIT BY STRIKING ANOTHER KEY."
120 LP=25: PP=66: AD=896: IF PEEK(AD)-160 THEN GOSUB 1000: REM READ DATA
140 PRINT ""; TAB(16); F$
150 INPUT "[145][206]AME OF ISSUE:"; F$
170 DV=4: INPUT "[208]RINTER [196]EVICE #:  4[157][157][157]"; DV
180 IF DV<3 OR DV>5 GOTO 170
190 IF DV=3 GOTO 230
210 SA=0: INPUT "[211]ECONDARY [193]DDRESS (LOWER CASE):  7[157][157][157]"; SA
230 OPEN 15, 8, 15, "I0"
250 REM GET TOTAL LINE COUNT
260 OPEN 2, 8, 2, F$
270 SYS AD
280 LN=VAL(A$)-1: PG=LN/LP
290 CLOSE 2
300 IF LN<1 OR PG<>INT(PG) THEN PRINT "FILE ERROR": CLOSE 15: STOP
320 INPUT "[198]IRST [208]AGE TO PRINT:  1[157][157][157]"; P$
330 PF=INT(VAL(P$)): IF PF<1 THEN PF=1
340 IF PF>PG THEN PF=PG
350 FL=(PF-1)*LP + 2
370 PRINT TAB(21); PG
380 INPUT "[145][198]INAL [208]AGE TO PRINT:"; P$
390 PL=INT(VAL(P$)): IF PL<1 THEN PL=1
400 IF PL>PG THEN PL=PG
410 IF PL<PF THEN PL=PF
420 LL=PL*LP + 1
440 REM FETCH & PRINT THE LINES
450 OPEN 2, 8, 2, F$
470 OPEN 4, DV, SA
490 LC=0
500 LM=1: CR=0
520 FOR I = FL TO LL
540 PRINT# 15, "P" + CHR$(2) + CHR$(I AND 255) + CHR$(I/256) + CHR$(1)
550 SYS AD
560 L=PEEK(142)
580 IF L THEN LM=1-LM: CR=0: GOTO 630
600 CR=CR+1: IF CR<3 OR LM GOTO 710
610 LM=1: GOTO 670
630 IF L=1 AND LEFT$(A$,L)=CHR$(32) THEN LM=1
650 PRINT#4, LEFT$(A$,L);
670 IF LM THEN PRINT#4: LC=LC+1
690 IF LC>PP-7 THEN LC=0: FOR J=1 TO 6: PRINT#4: NEXT
710 GET Z$: IF Z$="" GOTO 780
730 PRINT: PRINT "[208]RESS 'Q' TO QUIT, OTHER TO RESUME:[146] ?[157]";
740 GET Z$: IF Z$="" GOTO 740
750 IF Z$="Q" THEN PRINT "[209]UIT";: I=LL
760 PRINT
780 NEXT
800 CLOSE 2
810 FOR I=1 TO PP-LC: PRINT#4: NEXT
820 CLOSE4
830 END
899 REM ISSUE FILE NAME
900 DATA "JUL86"
999 REM READ & STORE ML
1000 CK=0: FOR I=AD TO AD+41: READ DA: POKE I,DA: CK=CK+DA: NEXT
1010 IF CK<>6121 THEN PRINT "ERROR IN DATA": STOP
1030 RETURN
1050 REM C64 STRING THING DATA (FILE 2)
1060 DATA 160,2,177,45,153,137,0,200,192,6,208,246,162,2
1070 DATA 32,198,255,32,228,255,201,13,240,15,164,142,145,140
1080 DATA 200,132,142,196,139,240,4,165,144,240,234,76,204,255